Macro: ac_set_releaseinfo_versioninfo_and_defines

Back to the Main Page. | Download the M4 Source.

# ac_set_releaseinfo_versioninfo_and_defines

Synopsis

  ``

Version

  1.2 (2001/08/25) guidod @ ac-archive-0.5.39

Author

  Guido Draheim <guidod@gmx.de>

Description
  AC_SET_RELEASEINFO_VERSIONINFO_AND_DEFINES [(VERSION)] -*- sh -*-
  `default $1 = $VERSION`

  check the $VERSION number and cut the two last digit-sequences off which will form a -version-info in a @VERSIONINFO@ ac_subst while the rest is going to the -release name in a @RELEASEINFO@ ac_subst.

  you should keep these two seperate - the release-name may contain alpha-characters and can be modified later with extra release-hints e.g. RELEASEINFO="$RELEASINFO-debug" for a debug version of your lib.

  `example: a VERSION="2.4.18" will be transformed into`
  `-release 2 -version-info 4:18`
  `and for a linux-target this will tell libtool to install the lib as`
  `libmy.so libmy.la libmy.a libmy-2.so.4 libmy-2.so.4.0.18`
  and executables will get link-resolve-infos for libmy-2.so.4 - therefore the patch-level is ignored during ldso linking, and ldso will use the one with the highest patchlevel. Using just "-release $(VERSION)" during libtool-linking would not do that - omitting the -version-info will libtool install libmy.so libmy.la libmy.a libmy-2.4.18.so and executables would get hardlinked with the 2.4.18 version of your lib.

  This background does also explain the default dll name for a win32 target : libtool will choose to make up libmy-2-4.dll for this version spec.

  Unlike the older/straight ac_set_releaseinfo_versioninfo this macro does set the three parts MAJOR_VERSION.;MINOR_VERSION.MICRO_VERSION from the VERSION-spec *and* does also ac_subst them like the two INFOs *and* the three version-parts are ac_defined numerically too. If you prefer a two-part VERSION-spec, the VERSION_REL will still be set, either to the host_cpu or just a simple "00", so watch out. You may add sublevel parts like "1.4.2-ac5" where the sublevel is just killed from these versioninfo/releasinfo substvars.

M4 Source Code

      AC_DEFUN([AC_SET_RELEASEINFO_VERSIONINFO_AND_DEFINES],
      [# ------ AC SET RELEASEINFO VERSIONINFO_AND_DEFINES --------------------------
      AC_MSG_CHECKING(version info)
        MINOR_VERSION=`echo ifelse( $1, , $VERSION, $1 )` # VERSION_TMP really...
        MAJOR_VERSION=`echo $MINOR_VERSION | sed -e 's/[[.]][[^.]]*$//'`  # delete micro
        MICRO_VERSION=`echo $MINOR_VERSION | sed -e "s/^$MAJOR_VERSION.//"` # the rest
        MINOR_VERSION=`echo $MAJOR_VERSION | sed -e 's/.*[[.]]//'`  # delete prefix now
        MICRO_VERSION=`echo $MICRO_VERSION | sed -e 's/[[^0-9]].*//'` # 5-p4 -> 5
        if test "$MINOR_VERSION" != "$MAJOR_VERSION" ; then # three-part version...
        MAJOR_VERSION=`echo $MAJOR_VERSION | sed -e "s/.$MINOR_VERSION\$//"`
        else # or has been two-part version - try using host_cpu if available
        MAJOR_VERSION="00" ; test "_$host_cpu" != "_" && MAJOR_VERSION="$host_cpu"
        fi
        RELEASEINFO="-release $MAJOR_VERSION"
        VERSIONINFO="-version-info $MINOR_VERSION:$MICRO_VERSION"
      AC_MSG_RESULT([$RELEASEINFO $VERSIONINFO])
      AC_SUBST([RELEASEINFO])
      AC_SUBST([VERSIONINFO])
      AC_SUBST([MAJOR_VERSION])
      AC_SUBST([MINOR_VERSION])
      AC_SUBST([MICRO_VERSION])
      AC_DEFINE_UNQUOTED([MAJOR_VERSION], $MAJOR_VERSION, [package major version])
      AC_DEFINE_UNQUOTED([MINOR_VERSION], $MINOR_VERSION, [package minor version])
      AC_DEFINE_UNQUOTED([MICRO_VERSION], $MICRO_VERSION, [package micro version])
      ])