Macro: ac_prog_perl_version

Back to the Main Page. | # ac_prog_perl_version | Download the M4 Source.

Synopsis

  `AC_PROG_PERL_VERSION(VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])`

Version

  1.1 (2002/12/12) Installed_Packages @ ac-archive-0.5.39

Author

  Dean Povey <povey@wedgetail.com>

Description

  Makes sure that perl supports the version indicated. If true the shell commands in ACTION-IF-TRUE are executed. If not the shell commands in ACTION-IF-FALSE are run. Note if $PERL is not set (for example by running AC_CHECK_PROG or AC_PATH_PROG), AC_CHECK_PROG(PERL, perl, perl) will be run.

  Example:

  `AC_PROG_PERL_VERSION(5.6.0)`

  This will check to make sure that the perl you have supports at least version 5.6.0.

M4 Source Code

      AC_DEFUN([AC_PROG_PERL_VERSION],[dnl
      # Make sure we have perl
      if test -z "$PERL"; then
      AC_CHECK_PROG(PERL,perl,perl)
      fi

      # Check if version of Perl is sufficient
      ac_perl_version="$1"

      if test "x$PERL" != "x"; then
        AC_MSG_CHECKING(for perl version greater than or equal to $ac_perl_version)
        # NB: It would be nice to log the error if there is one, but we cannot rely
        # on autoconf internals
        $PERL -e "use $ac_perl_version;" > /dev/null 2>&1
        if test $? -ne 0; then
          AC_MSG_RESULT(no);
          $3
        else
          AC_MSG_RESULT(ok);
          $2
        fi
      else
        AC_MSG_WARN(could not find perl)
      fi
      ])dnl